跳到主要內容

PostgreSQL - Unattended installation on windows

Introduction

要將別人軟體包裝到自己軟體中,不可或缺的東西就是Unattended installation。以Unattended installation來說,我們可以選擇透過Installer的silent mode安裝,也可以透過把目標軟體做成portable的版本。本篇文章分享這兩種方法,教導大家如何將PostgreSQL透過Unattended installation方式安裝到目標系統成為service。

Note. 本篇以PostgreSQL 10.7為例。

Install with installer

Tips

安裝程式或反安裝程式的參數,除了可以直接上官網搜尋Installation User Guide以外,也可以直接使用help參數查詢:
postgresql-10.7-2-windows-x64.exe --help
Windows安裝程式主要有EnterpriseDB與BigSQL兩種。BigSQL版本安裝元件是透過網路下載且支援參數不如EnterpriseDB版本多,以我們需求來說,我們傾向於使用EnterpriseDB版本。接下來分享給大家安裝與反安裝方法。

Installation

@echo off
set INSTALL_DIR=C:\postgres10
set INSTALLER=postgresql-10.7-2-windows-x64.exe
 
rem options for installation
set SSMDB_SERVICE=postgresql-10
set MODE=--unattendedmodeui none --mode unattended
 
set DB_PASSWD=--superpassword postgres
set DB_PORT=--serverport 5432
 
set SERVICE_NAME=--servicename %SSMDB_SERVICE%
 
set PREFIX=--prefix "%INSTALL_DIR%"
set DATA_DIR=--datadir "%INSTALL_DIR%\data"
 
set OPTIONS=%MODE% %PREFIX% %DB_PASSWD% %DATA_DIR% %DB_PORT% %SERVICE_NAME% --disable-components stackbuilder,pgAdmin
 
echo %INSTALLER% %OPTIONS%
%INSTALLER% %OPTIONS%
從我的batch變數名稱,大都可以猜出個別參數用途。我額外說明的參數如下:
  • prefix: 這指安裝目錄。(請注意如果要跳脫空白字元,請勿將反斜線放在最後,如“xxxx\”,否則會無法安裝)
  • disable-components: 不安裝的項目。以我的例子來說,我不需要將stackbuilder與pgAdmin安裝到目標系統上。
  • install_runtimes: 是否要安裝Visual C++ Redistributable Packages,預設是1,要安裝。

Un-installation

taskkill /f /im pgadmin4.exe
uninstall-postgresql.exe --mode unattended
這裡要特別做的是要kill pgadmin4的process,因為在uninstall postgresql時,它並不會去停止pgadmin4,這將導致pgadmin4殘留在系統中。假如你沒有安裝pgadmin,就不用管它。

Install with portable pack

Tips

把安裝完的東西複製一份出來並不困難,只要它的conf沒紀錄與路徑有關或相依於註冊檔內容,你有很大機會可以做成portable版本。按照以前在PostgreSQL 9.1的經驗,在我們還原備份出來的東西後,只要把service註冊好,就能夠正常使用了。

Portable Pack


在安裝完的postgresql中,我保留如上圖的內容。在備份之前,我先停止了原本正在執行的postgresql的service,並且砍掉了data/log的所有檔案。

Setup Visual C++ Redistributable Package

由於目標系統不一定已事先安裝好PostgreSQL執行所需要的libraries,因此在你的安裝程式中,必須記得去安裝Redistributable Pack。PostgreSQL在安裝目錄的installer資料夾中,已經提供了2013與2017兩個版本的Redistributable Pack。只要使用以下腳本就可以做silent mode安裝:
@echo off
set BASE=%~dp0
 
"%BASE%installer\vcredist_x64.exe" /install /quiet /norestart
"%BASE%installer\vcredist2017_x64.exe" /install /quiet /norestart
假如你希望安裝過程中可以彈出安裝redist畫面,可以將quiet改為passive,但缺點是會出現Cancel按鈕。

Setup Service & Remove Service

在將Portable pack部屬到目標系統並解開後,可以透過pg_ctl.exe去註冊service。我的工作目錄是在安裝目錄下,service名稱為postgresql-10:
@echo off
set BASE=%~dp0
 
set SERVICE=postgresql-10
set PG_CTL=%BASE%bin\pg_ctl.exe
set PG_DATA=%BASE%data
 
"%PG_CTL%" register -N "%SERVICE%" -D "%PG_DATA%" -w
假如要移除service,可以使用以下腳本:
@echo off
set SERVICE=postgresql-10
 
net stop %SERVICE%
sc delete %SERVICE%

Which one is better?

我提供以下幾點給大家參考去選擇:
  • 安裝速度: 在我筆電上透過Installer安裝真的非常久,因為它除了檔案的unpack外,還包含資料庫初始化流程。
  • 大小: 由於installer的內容經過更多的壓縮且某些資料是透過初始化產生的,所以installer會占用較少的空間。
  • 維護: 製作Portable包,肯定會比替換Installer來得費時。除非Installer的參數全改了。
  • 其它: 我比較擔心的是Portable版本是否會有Locale的問題,這點就等我之後有遇到再分享。


留言

這個網誌中的熱門文章

How to install RIDE on Windows?

Introduction 多年沒在Windows上開發RobotFramework,趁著這次整理一下RIDE安裝方法。 目前RIDE最新版本與Python對應版本如下: (3.6 < python <= 3.11) Install current released version (2.0.8.1) with: pip install -U robotframework-ride 安裝Python 直接到Python官網找尋最新的3.11版本,我使用3.11.9: link 。安裝就是一直下一步而已。 安裝wxPython 每次安裝RIDE最困難的都是wxPython。看了一下 官網 描述,我就姑且相信一下: 接著進入下 載頁面 就有安裝教學。基本上就是到Python目錄下的Scripts直接執行以下command: pip install -U wxPython 安裝RIDE 接著就如RIDE官網所說,執行以下command: pip install -U robotframework-ride 啟動RIDE 直接在相同目錄下執行ride就可以啟動了,你也可以直接在桌面建ride連結,加快下次啟動時間。 沒想到這次這麼順利就安裝完成了。因為我是使用java去啟動robot framework,就不特別講要怎麼使用pip安裝robot framework了。

Hello World!

即將要搬家,因此舊網頁內容將慢慢轉移至Blogger。 如果要存取舊網頁,可以使用以下連結: https://wiki.tonylin.idv.tw/dokuwiki/doku.php